# SPDX-License-Identifier: MPL-2.0
#
# Outils de mesure de l'essai de l'ADR 0013 (tools/measures/README.md). Point d'entrée :
# tools/measures/measure.ps1.

# --- sequa::measures : statistiques, en-tête et fichiers des rapports --------------------
# Partagé par le banc d'essai et par sequa-render (--measure-out), pour des rapports de
# même forme.
add_library(sequa_measures report/src/report.cpp)
add_library(sequa::measures ALIAS sequa_measures)
target_include_directories(sequa_measures PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}/report/include")
target_compile_features(sequa_measures PUBLIC cxx_std_20)
# Racine du dépôt : dossier par défaut des rapports (docs/migration/mesures/).
target_compile_definitions(sequa_measures PRIVATE SEQUA_SOURCE_DIR="${PROJECT_SOURCE_DIR}")
sequa_target_defaults(sequa_measures)

if(SEQUA_BUILD_SERVER)
    # --- Banc d'essai scene/delta (non installé) -----------------------------------------
    add_executable(sequa_scene_delta_bench bench/scene_delta_bench.cpp)
    set_target_properties(sequa_scene_delta_bench PROPERTIES OUTPUT_NAME sequa-scene-delta-bench)
    target_link_libraries(sequa_scene_delta_bench
        PRIVATE sequa::measures sequa::core sequa::core_render sequa::3d_wire)
    sequa_target_defaults(sequa_scene_delta_bench)
endif()

if(SEQUA_BUILD_TESTS)
    add_executable(sequa_measures_tests tests/main.cpp tests/test_report.cpp)
    target_link_libraries(sequa_measures_tests PRIVATE sequa::measures doctest::doctest)
    sequa_target_defaults(sequa_measures_tests)
    doctest_discover_tests(sequa_measures_tests)
    if(SEQUA_BUILD_SERVER)
        # Vérifie seulement que le banc tourne et que chaque message relu est identique.
        add_test(NAME sequa_scene_delta_bench_quick COMMAND sequa_scene_delta_bench --quick)
    endif()
endif()
