# SPDX-License-Identifier: MPL-2.0
#
# Adaptateur SEQUA 3D vers Godot (côté SEQUA). Godot lui-même se construit avec SCons en
# LibGodot (scripts/build-godot.ps1) ; avec SEQUA_BUILD_GODOT_RUNTIME, godot-cpp
# (../vendor/godot-cpp) est compilé ici pour piloter Godot depuis l'adaptateur (ADR 0007).

add_library(sequa_godot_adapter src/godot_adapter.cpp src/conversions.cpp src/input_mapping.cpp)
add_library(sequa::godot_adapter ALIAS sequa_godot_adapter)
# Le nom « sequa_godot_adapter » revient à la bibliothèque chargée (et à son .lib d'import).
set_target_properties(sequa_godot_adapter PROPERTIES OUTPUT_NAME sequa_godot_adapter_static)

target_include_directories(sequa_godot_adapter PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}/include")
target_link_libraries(sequa_godot_adapter PUBLIC sequa::3d)
sequa_target_defaults(sequa_godot_adapter)

if(SEQUA_BUILD_GODOT_RUNTIME)
    set(_godot_src "${PROJECT_SOURCE_DIR}/engines/godot/vendor/godot-src")
    # Variante de Godot (ADR 0010) : template_debug pour Debug, template_release sinon.
    if(CMAKE_BUILD_TYPE STREQUAL "Debug")
        set(_godot_target "template_debug")
    else()
        set(_godot_target "template_release")
    endif()
    set(SEQUA_GODOT_LIBRARY "${_godot_src}/bin/godot.windows.${_godot_target}.x86_64.dll"
        CACHE FILEPATH "Godot construit en bibliothèque (LibGodot)")
    get_filename_component(_godot_library_name "${SEQUA_GODOT_LIBRARY}" NAME)
    if(NOT WIN32)
        message(FATAL_ERROR "SEQUA_BUILD_GODOT_RUNTIME : Windows seulement pour l'instant")
    endif()
    if(NOT EXISTS "${SEQUA_GODOT_LIBRARY}")
        message(FATAL_ERROR "Godot absent (${SEQUA_GODOT_LIBRARY}) : lancer scripts/build-godot.ps1")
    endif()

    # Liste de l'API extraite du fork (scripts/build-godot.ps1 -Target editor, décision de
    # l'étape 3). À défaut, celle de godot-cpp pour la 4.7 : identique tant que le fork
    # n'ajoute rien à l'API.
    set(_godot_api "${PROJECT_SOURCE_DIR}/build/godot/extension_api.json")
    if(EXISTS "${_godot_api}")
        set(GODOTCPP_CUSTOM_API_FILE "${_godot_api}" CACHE FILEPATH "" FORCE)
        set(GODOTCPP_GDEXTENSION_DIR "${_godot_src}/core/extension" CACHE PATH "" FORCE)
        message(STATUS "godot-cpp : API du fork (${_godot_api})")
    else()
        set(GODOTCPP_CUSTOM_API_FILE "" CACHE FILEPATH "" FORCE)
        set(GODOTCPP_API_VERSION "4.7" CACHE STRING "" FORCE)
        message(STATUS "godot-cpp : API officielle 4.7 (extraire celle du fork : scripts/build-godot.ps1 -Target editor)")
    endif()
    set(GODOTCPP_TARGET "${_godot_target}" CACHE STRING "" FORCE)
    # Même bibliothèque d'exécution que le reste de SEQUA (/MD, /MDd en Debug) : godot-cpp
    # choisirait sinon /MT pour tout le projet.
    set(GODOTCPP_USE_STATIC_CPP OFF CACHE BOOL "" FORCE)
    set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>DLL" CACHE STRING "" FORCE)

    add_subdirectory("${PROJECT_SOURCE_DIR}/engines/godot/vendor/godot-cpp"
                     "${CMAKE_CURRENT_BINARY_DIR}/godot-cpp" EXCLUDE_FROM_ALL SYSTEM)
    # godot-cpp écrirait sinon ses .pdb dans <source>/bin.
    set_target_properties(godot-cpp PROPERTIES PDB_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/godot-cpp/bin")

    target_sources(sequa_godot_adapter PRIVATE src/godot_host.cpp src/godot_scene.cpp src/godot_input.cpp)
    target_link_libraries(sequa_godot_adapter PRIVATE godot::cpp sequa::layout)
    target_compile_definitions(sequa_godot_adapter PRIVATE SEQUA_GODOT_RUNTIME=1)

    # Bibliothèque chargée par sequa-render (ADR 0009) : point d'entrée C versionné.
    add_library(sequa_godot_adapter_module MODULE src/entry_point.cpp)
    set_target_properties(sequa_godot_adapter_module PROPERTIES OUTPUT_NAME sequa_godot_adapter PREFIX "")
    target_link_libraries(sequa_godot_adapter_module PRIVATE sequa::godot_adapter sequa::layout
        nlohmann_json::nlohmann_json)
    # Nom seul : la bibliothèque Godot est cherchée à côté de l'adaptateur (ADR 0010).
    target_compile_definitions(sequa_godot_adapter_module PRIVATE
        SEQUA_GODOT_LIBRARY_NAME="${_godot_library_name}")
    sequa_target_defaults(sequa_godot_adapter_module)

    # engines/godot/ : adaptateur, bibliothèque Godot et projet chargé par Godot.
    sequa_install_adapter(sequa_godot_adapter_module godot)
    install(FILES "${SEQUA_GODOT_LIBRARY}" DESTINATION engines/godot)
    install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/project/" DESTINATION engines/godot/project
        PATTERN ".godot" EXCLUDE PATTERN ".gitignore" EXCLUDE)

    # Démonstration de l'étape 3 : scène SIMULÉE poussée depuis SEQUA vers Godot. Outil de
    # développement, non installé : il désigne Godot et le projet dans le dépôt.
    add_executable(sequa_godot_demo demo/main.cpp)
    target_link_libraries(sequa_godot_demo PRIVATE sequa::godot_adapter)
    target_compile_definitions(sequa_godot_demo PRIVATE
        SEQUA_GODOT_DEMO_LIBRARY="${SEQUA_GODOT_LIBRARY}"
        SEQUA_GODOT_DEMO_PROJECT="${CMAKE_CURRENT_SOURCE_DIR}/project")
    sequa_target_defaults(sequa_godot_demo)
    if(SEQUA_BUILD_TESTS)
        add_test(NAME sequa_godot_demo COMMAND sequa_godot_demo --frames 300)
        set_tests_properties(sequa_godot_demo PROPERTIES LABELS "gpu;godot" TIMEOUT 120)
    endif()
else()
    target_compile_definitions(sequa_godot_adapter PRIVATE SEQUA_GODOT_RUNTIME=0)
endif()

if(SEQUA_BUILD_TESTS)
    add_executable(sequa_godot_adapter_tests tests/test_godot_adapter.cpp tests/test_conversions.cpp
        tests/test_input_mapping.cpp)
    target_link_libraries(sequa_godot_adapter_tests PRIVATE sequa::godot_adapter doctest::doctest)
    sequa_target_defaults(sequa_godot_adapter_tests)
    doctest_discover_tests(sequa_godot_adapter_tests)
endif()
